libs/samba/build.gradle.kts


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

plugins {
    alias(libs.plugins.android.library)
}

val shareDir = layout.buildDirectory.dir("test-share")
val dockerDir = layout.projectDirectory.dir("src/test/docker")

android {
    namespace = "org.the_jk.cleversync.samba"

    externalNativeBuild {
        cmake {
            path("CMakeLists.txt")
        }
    }

    buildTypes {
        debug {
            externalNativeBuild { cmake { cFlags += listOf("-g") } }
        }
        release {
            externalNativeBuild { cmake { cFlags += listOf("-O3") } }
        }
    }

    testOptions {
        unitTests {
            all { test ->
                test.doFirst {
                    shareDir.get().asFile.mkdirs()
                }

                test.systemProperty("dockerDir", dockerDir.toString())
                test.systemProperty("shareDir", shareDir.get().toString())
            }
        }
    }
}

dependencies {
    implementation(project(":libs:io"))
    testImplementation(project(":libs:utils"))
    testImplementation(project(":libs:test-utils"))
}

listOf("Debug", "Release").forEach { buildType ->
    val buildDir = project.layout.buildDirectory.dir("test-cpp/$buildType/build")

    val configure by tasks.register(
        "configureLibsFor${buildType}UnitTest",
        Exec::class
    ) {
        args(
            "-S",
            project.layout.projectDirectory.dir("."),
            "-B",
            buildDir.get()
        )
        executable = "cmake"
    }

    val compile by tasks.register(
        "compileLibsFor${buildType}UnitTest",
        Exec::class
    ) {
        dependsOn(configure)
        args("--build", buildDir.get())
        executable = "cmake"
    }

    val copy by tasks.register(
        "copyLibsFor${buildType}UnitTest",
        Copy::class
    ) {
        dependsOn(compile)
        from(buildDir.map { it.file("libsamba.so") })
        into(project.layout.projectDirectory.dir("src/test${buildType}/jniLibs"))
    }

    tasks.matching { it.name == "test${buildType}UnitTest" }.all {
        dependsOn(copy)
    }
}